SoftSharpen 8.8 - Script vidéo AviSynth

Message par **Dirk-Pitt** » sam. 01 sept., 2007 17:34

Sinon je suis en train de bosser dessus ...

J'utilise un enregistrement TV en HQ de Michel Vaillant fait avec un Sony RDR-HX1010 à patir de Canal Sat. J'ai 2 DVDs à monter ( 1 heure par DVD en HQ ). Voila le script:

Code : Tout sélectionner

LoadPlugin( "D:\_PlugIns_\DGIndex\DGDecode.dll" )
LoadPlugin( "D:\_PlugIns_\ColorMatrix\ColorMatrix.dll" )
LoadPlugin( "D:\_PlugIns_\NicAudio\NicAudio.dll" )
LoadPlugin( "D:\_PlugIns_\MaskTools-v1.5.6\MaskTools.dll" )
LoadPlugin( "D:\_PlugIns_\MVTools-v0.9.9.1\MVTools.dll" )
LoadPlugin( "D:\_PlugIns_\UnFilter_Avisynth_2.5_Alpha\UnFilter.dll" )
LoadPlugin( "D:\_PlugIns_\Deen\Deen.dll" )
LoadPlugin( "D:\_PlugIns_\MSharpen\MSharpen.dll" )
Import( "D:\_PlugIns_\HybridFuPP\HybridFuPP.avsi" )
LoadPlugin( "D:\_PlugIns_\Decomb\Decomb.dll" )
Import( "D:\_PlugIns_\SoftSharpen.avsi" )
# === First Part =====================================================
V1=MPEG2Source( "D:\Work\B\VTS_01_1.d2v" )
V1=ColorMatrix( V1, D2V="D:\Work\B\VTS_01_1.d2v" )
V1=AssumeTFF( V1 )
V1=Telecide( V1, Guide=2, Post=4 )
V1=Crop( V1, 18, 74, -14, -74 )
A1=NicAC3Source( "D:\Work\B\VTS_01_1 T01 2_0ch 256Kbps DELAY -128ms.ac3", 2, 1 ).DelayAudio( -0.128 )
# === Second Part ====================================================
V2=MPEG2Source( "D:\Work\C\VTS_01_1.d2v" )
V2=ColorMatrix( V2, D2V="D:\Work\C\VTS_01_1.d2v" )
V2=AssumeTFF( V2 )
V2=Telecide( V2, Guide=2, Post=4 )
V2=Crop( V2, 18, 74, -14, -74 )
A2=NicAC3Source( "D:\Work\C\VTS_01_1 T01 2_0ch 256Kbps DELAY -128ms.ac3", 2, 1 ).DelayAudio( -0.128 )
# === BilinearResize =================================================
O1=BilinearResize( V1, 640, 360 )
O1=AddBorders( O1, 0, 4, 0, 4, 0 )
O2=BilinearResize( V2, 640, 360 )
O2=AddBorders( O2, 0, 4, 0, 4, 0 )
# === SoftSharpen ====================================================
S1=SoftSharpen( V1, Larg=640, Haut=360 )
S1=AddBorders( S1, 0, 4, 0, 4, 0 )
S2=SoftSharpen( V2, Larg=640, Haut=360 )
S2=AddBorders( S2, 0, 4, 0, 4, 0 )
# === HybridFuPP =====================================================
H1=HybridFuPP( V1, 640, 360, Preset="very high" )
H1=AddBorders( H1, 0, 4, 0, 4, 0 )
H2=HybridFuPP( V2, 640, 360, Preset="very high" )
H2=AddBorders( H2, 0, 4, 0, 4, 0 )
# === Left Part ( HybridFuPP ) =======================================
L1=AudioDub( H1, A1 )
L1=Trim( L1, 131, 70378 )
L2=AudioDub( H2, A2 )
L2=Trim( L2, 649, 79264 )
L=AlignedSplice( L1, L2 )
L=Crop( L, 0, 0, - L.Width / 2, 0 )
# === Right Part ( SoftSharpen ) =====================================
R1=AudioDub( S1, A1 )
R1=Trim( R1, 131, 70378 )
R2=AudioDub( S2, A2 )
R2=Trim( R2, 649, 79264 )
R=AlignedSplice( R1, R2 )
R=Crop( R, R.Width / 2, 0, 0, 0 )
# === Final ==========================================================
C=StackHorizontal( L, R )
C=Trim( C, 2 * 60 * 25, -1 + 3 * 60 * 25 )
Return( C )

Le but est de faire une comparaison entre SoftSharpen et HybridFuPP. Par contre j'ai l'aissé les paramètres par défaut pour SoftSharpen. Un conseil sachant que la scène à encoder est une scène rapide de l'accident de la Vaillante ?

... à suivre.

leon1789 · Message par **leon1789** » sam. 01 sept., 2007 19:04

pepsilite a écrit :comment vois-tu les presets avec cette nouvelle mouture?

Les mouvements sont traités par le flou, le statique par le net. Au niveau compressibilité, le flou créé dans les objets en mouvement permet de compenser l'augmentation de netteté des objets statiques. Je crois qu'il faut donc que la valeur Flou soit au moins égale à celle de Net.

Une valeur élevée de Flou entraine une augmentation de la compressibilité de la vidéo : à bitrate moyen fixé (encodage multipasses), le codec aura un meilleur rendu sur l'image (image préalablement traitée par avisynth). De plus, si la vidéo est "sale", une valeur élevée de Flou ne fera pas de mal (je pense) car il y a un traitement de débruitage temporel dépendant de Flou... (et un débruitage spatial dépendant de Net).
C'est pourquoi, personnellement, je crois que Flou = 30 me convient. Mais avec cette valeur, le script agit assez durement sur l'image...

Plus la vidéo est mouvementée, plus la valeur de Net peut être élevée. Les animations sont en général très lentes, souvent seuls quelques traits de crayons bougent, et il n'est pas rare d'avoir plusieurs images identiques qui se suivent, donc je pense que Net doit rester faible dans ce cas. De plus, dans les animations, les couleurs sont peu nombreuses, donc un débruitage fort n'est pas trop à craindre (je crois).

Des presets ? C'est assez subjectif...
film rapide --> Flou = 30 et Net = 30
film lent, bonne qualité --> Flou = 20 et Net = 10
film lent, mauvaise qualité --> Flou = 30 et Net = 10
animation --> Flou = 30 et Net =5

Dirk-Pitt a écrit :Sinon je suis en train de bosser dessus ... à suivre.

super !

Je suis désolé que le script change tous le jours : faut que je me calme...

Message par **pepsilite** » sam. 01 sept., 2007 19:08

bon, dans ce cas, j'attends un peu l'acalmie ...

leon1789 · Message par **leon1789** » sam. 01 sept., 2007 19:11

Dirk-Pitt a écrit : Un conseil sachant que la scène à encoder est une scène rapide de l'accident de la Vaillante ?

Pour une scène rapide, les paramètres par défaut sont corrects. Tu peux mettre aussi (Flou=30, Net=30)...
J'espère qu'il y a au moins un passage lent pour que le sharp puisse se faire sentir un peu

Regarde bien si tu as enregistrée la SoftSharpen version 3.4 (je numérote maintenant, parce sinon on s'y perd...)

Un remarque sur ton script : tes videos sont font 640x360 (ou pas loin avec le AddBorder). Or 360 n'est pas un multiple de 16. Si tu encodes en DivX, ça diminue la qualité de l'encodage. Je ne connais pas les effets sur d'autres codecs.

Message par **Underground78** » sam. 01 sept., 2007 19:16

Je me demandais juste comment allait fonctionner le resize ? De un quand il n'y a pas de resize, de deux selon que l'on agrandisse ou l'on réduise et de trois si on préfère utiliser un autre resizer comme LanczosResize ou Lanczos4Resize ou un des SplineResize par exemple ...

leon1789 a écrit :Un remarque sur ton script : tes videos sont font 640x360 (ou pas loin avec le AddBorder). Or 360 n'est pas un multiple de 16. Si tu encodes en DivX, ça diminue la qualité de l'encodage. Je ne connais pas les effets sur d'autres codecs.

C'est vrai pour tous les codecs mais je crois que ça commence à s'améliorer maintenant que ça soit en matière de qualité et de vitesse ...

leon1789 · Message par **leon1789** » sam. 01 sept., 2007 19:17

pepsilite a écrit :bon, dans ce cas, j'attends un peu l'acalmie ...

oui, surtout que si quelqu'un me dit qu'il y a un truc qui cloche, je vais devoir modifié plus ou moins en profondeur... (Je croise les doigts pour que le jugement de Dirk-Pitt soit plutôt positif.)

Message par **Dirk-Pitt** » sam. 01 sept., 2007 19:19

leon1789 a écrit :Un remarque sur ton script : tes videos sont font 640x360 (ou pas loin avec le AddBorder). Or 360 n'est pas un multiple de 16. Si tu encodes en DivX, ça diminue la qualité de l'encodage. Je ne connais pas les effets sur d'autres codecs.

Regarde bien, le AddBorder est fait pour ça --> 640x368

J'ai déjà vu les effets de la chose http://www.forum.lauden.fr/regle-couleu ... vt250.html

Message par **Dirk-Pitt** » sam. 01 sept., 2007 19:21

leon1789 a écrit :Regarde bien si tu as enregistrée la SoftSharpen version 3.4 (je numérote maintenant, parce sinon on s'y perd...)

Zut, version 3.3

leon1789 · Message par **leon1789** » sam. 01 sept., 2007 19:27

Underground78 a écrit :Je me demandais juste comment allait fonctionner le resize ? De un quand il n'y a pas de resize,

Oui, question naturelle : regarde ma réponse postée plus haut le Mar 28 Aoû, 2007 21:37

Underground78 a écrit :de deux selon que l'on agrandisse ou l'on réduise

Tu veux dire qu'il faudrait choisir entre bilinear et bicubic ? oui, il faudrait choisir en fonction du resize. Regarde dans les messages plus haut (avec pepsilite et dirk-pitt) : j'ai fait le choix du bicubic car il est paramétrable... (et c'est aussi le resizer principal dans HybridFupp)

Underground78 a écrit :de trois si on préfère utiliser un autre resizer comme LanczosResize ou Lanczos4Resize ou un des SplineResize par exemple ...

Ben oui, je vois bien, on pourrait bien sûr faire comme dans HybridFuPP : on demande la commande de resize à l'utilisateur et on l'exécute dans SoftSharpen. Pour l'instant, je n'ai pas intégré cela (car je resize avant d'utiliser SoftSharpen), mais je peux le faire (ça coute une ligne de code) : ça vous paraît intéressant une telle possibilité ?

leon1789 · Message par **leon1789** » sam. 01 sept., 2007 19:32

Dirk-Pitt a écrit :
leon1789 a écrit :Un remarque sur ton script : tes videos sont font 640x360 (ou pas loin avec le AddBorder). Or 360 n'est pas un multiple de 16. Si tu encodes en DivX, ça diminue la qualité de l'encodage. Je ne connais pas les effets sur d'autres codecs.
Regarde bien, le AddBorder est fait pour ça --> 640x368
J'ai déjà vu les effets de la chose http://www.forum.lauden.fr/regle-couleu ... vt250.html

Exact ! 4+360+4

Personnellement, je me suis aperçu que la qualité d'un encodage divx avec une résolution non multiple de 16 est comparable à celle obtenue avec un bitrate inférieur de 100 à 300 kbps (!).

Dirk-Pitt a écrit :
leon1789 a écrit :Regarde bien si tu as enregistrée la SoftSharpen version 3.4 (je numérote maintenant, parce sinon on s'y perd...)
Zut, version 3.3

pas grave...

Message par **Dirk-Pitt** » sam. 01 sept., 2007 19:44

Mise à jour

Message par **Underground78** » sam. 01 sept., 2007 20:12

leon1789 a écrit :
Underground78 a écrit :de trois si on préfère utiliser un autre resizer comme LanczosResize ou Lanczos4Resize ou un des SplineResize par exemple ...
Ben oui, je vois bien, on pourrait bien sûr faire comme dans HybridFuPP : on demande la commande de resize à l'utilisateur et on l'exécute dans SoftSharpen. Pour l'instant, je n'ai pas intégré cela (car je resize avant d'utiliser SoftSharpen), mais je peux le faire (ça coute une ligne de code) : ça vous paraît intéressant une telle possibilité ?

Ouaip parce que pour Pepsi je pense que ça sera simple de gérer après déjà pour choisir entre bilinear et bicubic ...

leon1789 · Message par **leon1789** » sam. 01 sept., 2007 21:43

Underground78 a écrit : Ouaip parce que pour Pepsi je pense que ça sera simple de gérer après déjà pour choisir entre bilinear et bicubic ...

ok, je le fais ce soir (une option "resize" pour laisser le choix à l'utilisateur), mais il me faudrait des précisions : tu veux quel genre d'instruction parmi les suivantes ?
-- SoftSharpen(..., resize="Lanczos4Resize", haut=640, larg=368...) : là, on précise la méthode, puis les dimensions
-- SoftSharpen(..., resize="BilinearResize(640,360).AddBorder(0,4,0,4)", ...) : là, on précise carrément toute l'instruction
-- autres ........?

Message par **patlepsycho** » dim. 02 sept., 2007 9:25

C'est conseillé pour l'animé softsharpen ou pas ?
j'ai fais un essais avec (Flou=30, Net=30). et c'est pas concluant, les objets en mouvement sont trop flou et les statiques sont net mais les aplats pas très propre, en plus c'est plus lent que fupp.

Message par **Underground78** » dim. 02 sept., 2007 9:34

leon1789 a écrit :
Underground78 a écrit : Ouaip parce que pour Pepsi je pense que ça sera simple de gérer après déjà pour choisir entre bilinear et bicubic ...
ok, je le fais ce soir (une option "resize" pour laisser le choix à l'utilisateur), mais il me faudrait des précisions : tu veux quel genre d'instruction parmi les suivantes ?
-- SoftSharpen(..., resize="Lanczos4Resize", haut=640, larg=368...) : là, on précise la méthode, puis les dimensions
-- SoftSharpen(..., resize="BilinearResize(640,360).AddBorder(0,4,0,4)", ...) : là, on précise carrément toute l'instruction
-- autres ........?

Je pense que la première solution est pas mal mais faudrait voir avec Pepsi ce qui l'arrange le plus (et surtout si ça l'arrangerait vraiment) ...

Sinon petite question pour satisfaire ma curiosité personnelle. Si j'ai bien compris, ton script traite différemment les différentes zones de l'image selon qu'il y est du mouvement ou non. Je suppose donc que tu "découpes" l'image en petits morceaux pour cela, est-ce qu'il y a moyen de choisir la précision du traitement en choisissant la taille du découpage en gros ? Ca permettrait peut-être de jouer sur la rapidité du script (avec évidemment une perte de qualité) ... Enfin il est possible que ça ne marche pas du tout comme ça donc ...

leon1789 · Message par **leon1789** » dim. 02 sept., 2007 10:35

patlepsycho, merci pour ton test sur anime

patlepsycho a écrit :C'est conseillé pour l'animé softsharpen ou pas ?

L'animé ne convient pas vraiment car il y a très peu de mouvement, donc peu de bits à gagner et à réinjecter (indirectement) dans les objets nets. Sauf exception, il faut plutôt Net=5 pour une anime, pas davantage je pense sinon on perd bcp trop en compressibilité ce qui implique :
- une augmentation de bitrate si on fait un encodage unipasse basé sur la qualité.
- une dégradation générale de l'image si on fait du multipasse.

Pour connaître une valeur ad hoc de Net, on peut encoder (en une passe, sur 5% de la vidéo) avec l'option EstimNet : SoftSharpen(EstimNet=true).

patlepsycho a écrit :j'ai fais un essais avec (Flou=30, Net=30). et c'est pas concluant, les objets en mouvement sont trop flou et les statiques sont net mais les aplats pas très propre

Flou=30 ne te convient visiblement pas : peut-être Flou=15 ?...

patlepsycho a écrit :en plus c'est plus lent que fupp.

oui, c'est un gros problème : le temps d'une compression est facilement 25% plus important qu'avec hybridfupp...

En résumé : pour une anime, il faudrait voir SoftSharpen(15,5) qui serait plus raisonnable, avec un temps de calcul toujours très important...
Conclusion : le peu d'effets positifs de SoftSharpen(15,5) n'en vaut pas la chandelle pour une anime.

Message par **Dirk-Pitt** » dim. 02 sept., 2007 10:36

J'ai un peu changé mon script de test. Je mets ici que la fin qui a changé:

Code : Tout sélectionner

# === Part 1 ( BilinearResize ) ======================================
L1=AudioDub( O1, A1 )
L1=Trim( L1, 131, 70378 )
L2=AudioDub( O2, A2 )
L2=Trim( L2, 649, 79264 )
L=AlignedSplice( L1, L2 )
L=Crop( L, 0, 0, - ( L.Width - 212 ), 0 )
L=SubTitle( L, "BilinearResize", Align=2 )
# === Part 2 ( SoftSharpen ) =========================================
M1=AudioDub( S1, A1 )
M1=Trim( M1, 131, 70378 )
M2=AudioDub( S2, A2 )
M2=Trim( M2, 649, 79264 )
M=AlignedSplice( M1, M2 )
M=Crop( M, 212 + 2, 0, - ( 212 + 2), 0 )
M=SubTitle( M, "SoftSharpen", Align=2 )
# === Part 3 ( HybridFuPP ) ==========================================
R1=AudioDub( H1, A1 )
R1=Trim( R1, 131, 70378 )
R2=AudioDub( H2, A2 )
R2=Trim( R2, 649, 79264 )
R=AlignedSplice( R1, R2 )
R=Crop( R, R.Width - 212, 0, 0, 0 )
R=SubTitle( R, "HybridFuPP", Align=2 )
# === Separator ======================================================
B=BlankClip( Length=L.Framecount, Width=2, Height=L.Height, Fps=L.Framerate, Color=color_gray10 ).ConvertToYV12( Interlaced=False )
# === Final ==========================================================
C=StackHorizontal( L, B, M, B, R )
C=Trim( C, 2 * 60 * 25, -1 + 3 * 60 * 25 )
Return( C )

Je découpe maintenant en 3 parties: BilinearResize, SoftSharpen et HybridFuPP. J'ajoute le nom du traitement en sous titre et j'intercale un petit séparateur. À l'affichage ça donne ça:

Je vais essayer de lancer l'encodage complet ce soir ... à suivre.

leon1789 · Message par **leon1789** » dim. 02 sept., 2007 10:57

Underground78 a écrit : Sinon petite question pour satisfaire ma curiosité personnelle. Si j'ai bien compris, ton script traite différemment les différentes zones de l'image selon qu'il y est du mouvement ou non.

plus précisément, le traitement se fait en fonction de la vitesse du mouvement.

Underground78 a écrit : Je suppose donc que tu "découpes" l'image en petits morceaux pour cela, est-ce qu'il y a moyen de choisir la précision du traitement en choisissant la taille du découpage en gros ?

C'est MVTools qui découpe

oui, il y a une précision à donner :
Video.MVMask(Video.MVAnalyse(16,isb=false), ml=20)

Le 16 a un rôle dans la précision de la détection, mais, à mon avis, c'est la variable ml qui joue le rôle principal. Hier soir, je me suis aperçu que je l'avais réglée un peu trop "agressive" (i.e. trop basse) : ml = 26 me paraît maintenant plus indiquée (--> Version 3.5 de SoftSharpen...

), car ainsi l'analyse de la vitesse du mouvement est plus fine, et du coup je peux espérer mieux ajuster le flou sur les objets en mouvement.

Le problème, c'est aussi de trouver une bonne manière de flouter (suffisamment, mais pas trop) les objets en mouvement...

Underground78 a écrit : Ca permettrait peut-être de jouer sur la rapidité du script (avec évidemment une perte de qualité)

Question vitesse (ou lenteur !), le 16 (qui n'est pas la valeur par défaut de MVAnalyse) est là pour faire exactement comme tu le dis : +rapide dans la détection, -de qualité (mais elle reste suffisante).

Le gros problème lié à la vitesse, c'est aussi (surtout ?) tout le reste du script...

leon1789 · Message par **leon1789** » dim. 02 sept., 2007 11:04

Dirk-Pitt a écrit :J'ai un peu changé mon script de test. Je mets ici que la fin qui a changé: (...)
Je vais essayer de lancer l'encodage complet ce soir ... à suivre.

très jolis contenant et contenu

(Sur l'image, SoftSharpen a l'air plus flou, mais peut-être que la personne est en mouvement... )

une remarque : pourquoi fais-tu du audiodub avec chaque partie d'image, donc trois fois ? pourquoi ne pas le faire une seule fois à la fin du script ?

Message par **Dirk-Pitt** » dim. 02 sept., 2007 11:22

leon1789 a écrit :une remarque : pourquoi fais-tu du audiodub avec chaque partie d'image, donc trois fois ? pourquoi ne pas le faire une seule fois à la fin du script ?

C'est à cause des Trims. Le but est de découper l'audio et la vidéo en même temps pour ne pas avoir de décalage. Cela dit, je dois pouvoir optimiser. Si je considère que film=partie1+partie2 ( non trimées ), je dois pouvoir faire passer cela dans mon binz à 3 parties et au final ajouter l'AudioDub et les Trims qui vont bien.
Je vais essayer ... mais j'ai aussi du php à faire.

leon1789 · Message par **leon1789** » dim. 02 sept., 2007 11:52

Dirk-Pitt a écrit :C'est à cause des Trims. Le but est de découper l'audio et la vidéo en même temps pour ne pas avoir de décalage. Cela dit, je dois pouvoir optimiser. Si je considère que film=partie1+partie2 ( non trimées ), je dois pouvoir faire passer cela dans mon binz à 3 parties et au final ajouter l'AudioDub et les Trims qui vont bien.
Je vais essayer ... mais j'ai aussi du php à faire.

oui, tu colles deux films, donc deux pistes audios A1 et A2. Mais en commentant simplement les lignes mettant le son dans M1,M2 et R1,R2, le son viendra quand même de L1 + L2, non ?
Mais tout ça n'est pas en lien avec le test vidéo de toute manière

Message par **Dirk-Pitt** » dim. 02 sept., 2007 12:34

leon1789 a écrit :oui, tu colles deux films, donc deux pistes audios A1 et A2. Mais en commentant simplement les lignes mettant le son dans M1,M2 et R1,R2, le son viendra quand même de L1 + L2, non ?

Bien vu.

J'ai réorgasiné le tout de la manière suivante:

Code : Tout sélectionner

# === BilinearResize =================================================
O1=BilinearResize( V1, 640, 360 )
O1=Crop( O1, 0, 0, - ( O1.Width - 212 ), 0 )
O1=SubTitle( O1, "BilinearResize", Align=2 )
O2=BilinearResize( V2, 640, 360 )
O2=Crop( O2, 0, 0, - ( O2.Width - 212 ), 0 )
O2=SubTitle( O2, "BilinearResize", Align=2 )
# === Separator ======================================================
B1=BlankClip( Length=O1.Framecount, Width=2, Height=O1.Height, Fps=O1.Framerate, Color=color_gray10 ).ConvertToYV12( Interlaced=False )
B2=BlankClip( Length=O2.Framecount, Width=2, Height=O2.Height, Fps=O2.Framerate, Color=color_gray10 ).ConvertToYV12( Interlaced=False )
# === SoftSharpen ====================================================
S1=SoftSharpen( V1, Larg=640, Haut=360 )
S1=Crop( S1, 212 + 2, 0, - ( 212 + 2), 0 )
S1=SubTitle( S1, "SoftSharpen", Align=2 )
S2=SoftSharpen( V2, Larg=640, Haut=360 )
S2=Crop( S2, 212 + 2, 0, - ( 212 + 2), 0 )
S2=SubTitle( S2, "SoftSharpen", Align=2 )
# === HybridFuPP =====================================================
H1=HybridFuPP( V1, 640, 360, Preset="very high" )
H1=Crop( H1, H1.Width - 212, 0, 0, 0 )
H1=SubTitle( H1, "HybridFuPP", Align=2 )
H2=HybridFuPP( V2, 640, 360, Preset="very high" )
H2=Crop( H2, H2.Width - 212, 0, 0, 0 )
H2=SubTitle( H2, "HybridFuPP", Align=2 )
# === Final ==========================================================
C1=StackHorizontal( O1, B1, S1, B1, H1 )
C1=AudioDub( C1, A1 )
C1=Trim( C1, 131, 70378 )
C2=StackHorizontal( O2, B2, S2, B2, H2 )
C2=AudioDub( C2, A2 )
C2=Trim( C2, 649, 79264 )
C=AlignedSplice( C1, C2 )
C=Trim( C, 39 * 60 * 25, -1 + 41 * 60 * 25 )
Return( C )

leon1789 a écrit :Mais tout ça n'est pas en lien avec le test vidéo de toute manière

En effet, oui.

Message par **Dirk-Pitt** » dim. 02 sept., 2007 14:25

Le dernier, promis:

Code : Tout sélectionner

# === Main Clip, BilinearResize ======================================
O1=BilinearResize( V1, 640, 360 )
O1=AudioDub( O1, A1 )
O1=Trim( O1, 131, 70378 )
O2=BilinearResize( V2, 640, 360 )
O2=AudioDub( O2, A2 )
O2=Trim( O2, 649, 79264 )
O=AlignedSplice( O1, O2 )
# === Separator ======================================================
B=BlankClip( Length=O.Framecount, Width=2, Height=O.Height, Fps=O.Framerate, Color=color_gray10 ).ConvertToYV12( Interlaced=False )
# === Video Only =====================================================
V=AlignedSplice( Trim( V1, 131, 70378 ), Trim( V2, 649, 79264 ) )
# === SoftSharpen ====================================================
S=SoftSharpen( V, Larg=640, Haut=360 )
# === SoftSharpen =====================================================
H=HybridFuPP( V, 640, 360, Preset="very high" )
# === Stack Horizontal ===============================================
O=Crop( O, 0, 0, - ( O.Width - 212 ), 0 )
O=SubTitle( O, "BilinearResize", Align=2 )
S=Crop( S, 212 + 2, 0, - ( 212 + 2), 0 )
S=SubTitle( S, "SoftSharpen", Align=2 )
H=Crop( H, H.Width - 212, 0, 0, 0 )
H=SubTitle( H, "HybridFuPP", Align=2 )
C=StackHorizontal( O, B, S, B, H )
# === Final ==========================================================
C=AddBorders( C, 0, 4, 0, 4, 0 )
C=Trim( C, 39 * 60 * 25, -1 + 41 * 60 * 25 )
Return( C )

leon1789 · Message par **leon1789** » dim. 02 sept., 2007 15:10

Dirk-Pitt a écrit :Le dernier, promis:

Ca me rassure de ne pas être le seul à modifier sans cesse ses scripts...

Message par **Dirk-Pitt** » dim. 02 sept., 2007 15:27

Exact